In the following example, we take a list of integers and pass it to the Enum.uniq/1 function which removes duplicates from the list without altering the original order of the remaining elements.

list = [1, 2, 2, 3, 3, 1, 2, 4]
Enum.uniq(list) # Returns [1, 2, 3, 4]

If you are trying to only remove consecutive duplicate elements, then there is Enum.dedup/1:

list = [1, 2, 2, 3, 3, 1, 2, 4]
Enum.dedup(list) # Returns [1, 2, 3, 1, 2, 4]

(Note: We append /1 simply as a notation indicating the arity of a function, that is how many arguments it accepts. my_func/1 accepts one argument, my_func/2 two, and so on.)

Enum is full of helpful functions when working with collection data types that implement the Enumerable protocol (e.g., lists, maps, ranges, streams, etc.) and it’s worth getting acquainted with.

Removing duplicates using recursion

Alright, Elixir does the heavy lifting for us in this case, but how would we go about removing duplicates from a list in Elixir without using Enum.uniq/1? I mean from scratch, simply using recursion without relying on Enum, sets, :lists.usort/1, etc.

It is worth asking such a question to both exercise our recursion muscle (something that doesn’t come naturally to most programmers) and so that we’re ready to handle conceptually similar problems that do not have pre-made functions but could benefit from a recursive solution.

There are likely a few ways to implement this, but this what sprang to mind when I thought about it:

defmodule MyList do
  def uniq([]), do: []

  def uniq([head | tail]) do
    [head | for(x <- uniq(tail), x != head, do: x)]
  end
end

Calling MyList.uniq(list) will then return the same list without duplicates as Enum.uniq(list)did. (Although, it’s worth noting, that we implemented a List-specific version of the uniq/1 function).

Let’s see how this works. If the list is empty (i.e., []) we obviously return an empty list, as there is nothing to remove. This is our base case for the recursion.

If the list is not empty, it will have a head and a tail, and we use Elixir’s pattern matching to bind the first element of the list passed to the function to head and the rest of the elements to the list tail.

Note that a proper list with a single element will simply have an empty list as its tail. So writing [3] is equivalent to writing [3|[]] where 3 is the head, [] is the tail, and | is the cons operator (short for constructor operator, as it’s used to construct lists).

So far so good. Here is where things get a little trickier. Let’s analyze this line:

    [head | for(x <- uniq(tail), x != head, do: x)]

The code is wrapped in square brackets [...]which means that we are returning a list. Then you’ll notice the | cons operator. So we are constructing a list that has head as its first element and whatever the rest of that line of code does, as its tail.

This makes sense if you think about it. Sure, the list might have duplicates, but the first element will always be included. If a duplicate of the first element exists, that’s the one that is going to be removed and not the first element.

So we are building a list and the first element of the original list is also the first element of our deduplicated list. What goes into the rest of the list?

Comprehensions

We see a for. Unlike many programming languages, for is not a loop keyword in Elixir. Rather, it is used for comprehensions (a form of syntax sugar to generate lists from existing collections). Syntax, which is not too different from mathematical notation.

Here is a simple example of how to use them:

for x <- [1, 2, 3, 4], do: x + x # Returns [2, 4, 6, 8]

“For each element x in [1, 2, 3, 4] do x + x and put the result in a list.”

It also accepts filters, which allows us to specify a condition:

for x <- [1, 2, 3, 4], x < 3, do: x + x # Returns [2, 4]

In this example, the condition is that x is smaller than 3, so only the first two elements, which are lesser than 3, get doubled and added to the resulting list.

Recursing our way to the base case

OK, back to our “cryptic” line:

    [head | for(x <- uniq(tail), x != head, do: x)]

head is our first element and then we are using a comprehension to generate a list without duplicates.

We are saying, for each x in a deduplicated tail, add x to the list if it’s different from our first element head.

The part that gets people weirded out about is recursively calling uniq(tail). We can get away with this because we have a base case that ensures we don’t recurse forever.

At each call of uniq(tail) we are making the tail shorter by one element.

For example, executing MyList.uniq([1, 2, 3, 3]) will make the following recursive calls:

• MyList.uniq([1, 2, 3, 3])
• MyList.uniq([2, 3, 3])
• MyList.uniq([3, 3])
• MyList.uniq([3])
• MyList.uniq([])

When we eventually get to the tail being [], which is our base case,[] is returned and MyList.uniq/1 is no longer called.

Recursion can be hard to grasp at first, but it’s a powerful tool and a staple of functional programming, so it’s well worth practicing.

As pointed out in the comment section, this implementation is quite illustrative but not very efficient. In production, you’d want to opt for the built-in functions or implement a tail-recursive version that leverages MapSet. And although tail recursion is faster in this case, it’s worth noting that even that is not a silver bullet.

The post Removing Duplicates From a List in Elixir appeared first on Programming Zen.

You’ll need to edit your config/dev.exs configuration file to change the host key as follows:

http: [port: System.get_env("PORT", "4000")],

System.get_env("PORT", "4000") retrieves the value of the PORT environment variable if one has been set. If the environment doesn’t have the specified variable (i.e., PORT), it will default to 4000.

You can then boot your Phoenix server by passing the variable value to the command as follows:

$ PORT=5000 mix phx.server

This will run the server on the port you specified, in this example 5000.

The name of the environment variable is arbitrary. We used PORT but we could have opted for PHX_PORT or something else altogether. Just so long as your configuration file and environment use the same name.

You can, of course, set the environment variable outside of the mix phx.server command, for example in your shell profile.

The post Specify a Port when Booting a Phoenix Application appeared first on Programming Zen.

Simple enough, but there is more than meets the eye.

Elixir String Length

In Elixir, you can return the number of characters in a string with the String.length/1 function:

String.length("Antonio") # 7
String.length("")        # 0
String.length("résumé")  # 6

Discussion

In the case of a string like, "Antonio", there isn’t much to discuss. String.length("Antonio") returns the number of characters in the string.

The string clearly has 7 characters and since each character in this particular string can be represented with a single byte, its raw representation is 7 bytes as well.

Things become more interesting when a string contains special characters.

Consider the string, "résumé". In this case, String.length/1 returns 6. You can think of this as the number of “visible” or “user-perceived” characters in the string. However, let’s investigate its raw representation:

iex(2)> i "résumé"
Term
  "résumé"
Data type
  BitString
Byte size
  8
Description
  This is a string: a UTF-8 encoded binary. It's printed surrounded by
  "double quotes" because all UTF-8 encoded code points in it are printable.
Raw representation
  <<114, 195, 169, 115, 117, 109, 195, 169>>
Reference modules
  String, :binary
Implemented protocols
  Collectable, IEx.Info, Inspect, List.Chars, String.Chars

You’ll notice that the string’s actual data type is BitString. Specifically, this binary is made up of 8 bytes, even though there are only 6 user-perceived characters. This is because it takes 2 bytes to represent its accented é characters.

If you are interested in the number of bytes within a string, instead of its length, you can use the Kernel.byte_size/1 function:

iex(3)> string = "résumé"
"résumé"

iex(4)> String.length(string)
6

iex(5)> byte_size(string)
8

From a performance standpoint, it’s worth noting that Kernel.byte_size/1 is more efficient than String.length/1. Unlike the latter, which takes longer as the string grows, Kernel.byte_size/1 will return in constant time.

Strings in Elixir are UTF-8 encoded binaries. You can think of them as collections of code points. A code point is a Unicode character, whose underlying representation might require one or more bytes. For example, the é characters in the string "résumé" are code points whose representation requires two bytes each.

The Unicode standard also defines some special characters as the combination of other characters. In other words, even though they appear to the reader as a single character, they are in fact a combination of two or more code points. These are known as grapheme clusters.

For example, the e-acute letter can be represented as a single code point as we’ve done so far (this is also known as a precomposed character) or as a combination of two code points (the letter e and a combining acute accent). These look the same but they are technically two different characters as far as Elixir is concerned; so the two strings below end up representing two different binaries:

iex(6)> "é" == "é"
false

When working with strings, you’ll often want to consider them in terms of the user-perceived characters, rather than their code points or the binary they actually represent.

To help us out, the Elixir String module provides us with String.graphemes/1 which returns a list of characters, without splitting grapheme clusters into the underlying code points. If you need the codepoints, you can always use String.codepoints/1.

To see the distinction between code points and graphemes in action, consider the following string (using the grapheme cluster built from two code points):

iex(7)> String.codepoints("cliché")
["c", "l", "i", "c", "h", "e", "́"]

iex(8)> String.graphemes("cliché")
["c", "l", "i", "c", "h", "é"]

As you can see, String.codepoints/1 shows us a list of code points in the string, and the special e-acute gets split into two code points. If you look closely, you’ll notice the accent as the last code point in the list.

String.graphemes/1 simply returns the list of graphemes and is the closest thing that we have to a function that provides a list of user-perceived characters.

Now, consider its length and byte size:

ie(9)> String.length("cliché")
6

iex(10)> byte_size("cliché")
8

String.length/1 returns 6, the number of user-perceived characters in the string. Kernel.byte_size/1 returns 8 because it takes 3 bytes to represent the special character/grapheme (1 for the letter e, and 2 for the combining acute accent).

We used the expression “visible” or “user-perceived” characters to give us an intuitive understanding. Now that you know more about bytes, code points, and graphemes, we can be a little more precise and say that String.length/1 returns the number of graphemes in a string.

Finally, if you wanted to know the number of codepoints, you could trivially compose the Kernel.length/1 function and the String.codepoints/1 function:

"cliché"
  |> String.codepoints()
  |> length()

Note that if you are trying this in IEx, you’ll need to use the backslash character to continue on new lines:

iex(11)> "cliché" \
...(11)> |> String.codepoints() \
...(11)> |> length()
7

So in summary, our string contains 6 graphemes, 7 code points, and 8 bytes.

The post String Length in Elixir appeared first on Programming Zen.

As you likely know, a Hello World is a very simple program that displays the phrase, Hello, World!

Our Elixir Hello World might not be too exciting but it will allow us to discuss quite a few fundamental concepts.

Hello World in Elixir

As you might expect, this is very straightforward:

IO.puts("Hello, World!")

How to run it

The easiest way to run this line of code is to launch IEx (i.e., Interactive Elixir). This will also act as a sanity test to ensure that you have installed Elixir correctly on your machine.

$ iex
Erlang/OTP 22 [erts-10.4.4] [source] [64-bit] [smp:8:8] [ds:8:8:10] [async-threads:1] [hipe] [dtrace]

Interactive Elixir (1.9.1) - press Ctrl+C to exit (type h() ENTER for help)
iex(1)> 

For the best experience on Windows, including tab-based autocompletion in IEx, it’s worth passing the --werl flag to IEx or permanently enabling it by setting the environment variable IEX_WITH_WERL to true.

C:\> iex --werl

Once you type your Elixir Hello World and press enter, IEx will print out the message Hello, World! and then display the return value of the function, which is the atom :ok¹ (indicating that the function executed successfully):

iex(2)> IO.puts("Hello, World!")
Hello, World!
:ok
iex(3)>

Alternatively, you could place our one-liner in a hello.exs file and execute it as a script:

$ elixir hello.exs
Hello, World!

You could also create a whole (Mix) project for this, but arguably that is overkill for our humble Hello World.

Discussion

puts is a function that prints a message and adds a newline character. write is the variant that does the same but doesn’t append a newline. They both belong to the IO module, a module that includes, as the name implies, various functions for handling input and output.

At any time, we can learn more about a function by using the h helper within IEx:

iex(3)> h IO.puts

                        def puts(device \\ :stdio, item)

  @spec puts(device(), chardata() | String.Chars.t()) :: :ok

Writes item to the given device, similar to write/2, but adds a newline at the
end.

By default, the device is the standard output. It returns :ok if it succeeds.

## Examples

    IO.puts("Hello World!")
    #=> Hello World!

    IO.puts(:stderr, "error")
    #=> error

iex(4)>

Unlike languages like Python and Ruby, in Elixir you need to use a qualified call that includes the module name in order to invoke this function.

If we don’t qualify the call, we get a compile error:

iex(4)> puts("Hello, World!")
** (CompileError) iex:1: undefined function puts/1

If you wanted to omit the module name, you could import the module (i.e., import IO) beforehand, or more realistically, limit the import to the function(s) that you need:

import IO, only: [puts: 1]

puts("Hello, World!")

That puts: 1 indicates that we are specifically importing the version of the function that accepts one argument. You’ll see that function referred to as IO.puts/1 and we say that it has an arity of one or it’s a one-arity function.

The arity of a function (i.e., the number of arguments it accepts) is important because in Elixir you can have functions with the same name but different arities.

In fact, there are technically two variants of the puts function, IO.puts/1 which we just used, and IO.puts/2 which also allows us to specify an IO device as its first argument. (I say technically because they are both declared within a single function definition.)

By default, the function prints to the standard output. This can be easily verified by looking at the Elixir source code:

def puts(device \\ :stdio, item) do
  :io.put_chars(map_dev(device), [to_chardata(item), ?\n])
end

As you can see, the underlying implementation makes a call to the Erlang’s IO.put_chars/2 function.

What’s worth noting here is that:

• In Elixir, default parameters can be specified using \\.
• The default IO device for the function is the atom :stdio which maps to :standard_io in Erlang. Basically, by default, it will print to your stdout unless you pass a different device to the function.
• Another common value for the device is :stderr which is a shortcut for Erlang’s :standard_error.
• When we call the function without a device (leveraging the default parameter) we are calling IO.puts/1. When we pass it a device as its first argument and a string as its second argument, we are calling IO.puts/2.

In practice, you’ll most commonly use IO.puts/2 when printing to the standard error, instead of the standard output:

iex(5)> IO.puts(:stderr, "Hello, Post-Apocalyptic World!")
Hello, Post-Apocalyptic World!
:ok

For such messages, there are also IO.warn/1 (used below) and IO.warn/2 which output to the standard error and in addition, include a stacktrace (provided by the developer in the case of IO.warn/2).

iex(6)> IO.warn("Hello, Post-Apocalyptic World!")
warning: Hello, Post-Apocalyptic World!
  (stdlib) erl_eval.erl:680: :erl_eval.do_apply/6
  (elixir) src/elixir.erl:275: :elixir.eval_forms/4
  (iex) lib/iex/evaluator.ex:257: IEx.Evaluator.handle_eval/5
  (iex) lib/iex/evaluator.ex:237: IEx.Evaluator.do_eval/3
  (iex) lib/iex/evaluator.ex:215: IEx.Evaluator.eval/3

:ok

In most cases, parentheses are optional in Elixir, so we could omit them.²

IO.puts "Hello, World!"

It’s worth noting that strings are double-quoted literals in Elixir. Unlike other languages, single-quoted literals are not an alternative way of representing strings.

In Elixir, single-quoted literals represent a related but ultimately different datatype (i.e., List), as we can verify by using the handy data type information helper i in IEx:

iex(7)> i "Hello, World!"
Term
  "Hello, World!"
Data type
  BitString
Byte size
  13
Description
  This is a string: a UTF-8 encoded binary. It's printed surrounded by
  "double quotes" because all UTF-8 encoded code points in it are printable.
Raw representation
  <<72, 101, 108, 108, 111, 44, 32, 87, 111, 114, 108, 100, 33>>
Reference modules
  String, :binary
Implemented protocols
  Collectable, IEx.Info, Inspect, List.Chars, String.Chars

iex(8)> i 'Hello, World!'
Term
  'Hello, World!'
Data type
  List
Description
  This is a list of integers that is printed as a sequence of characters
  delimited by single quotes because all the integers in it represent printable
  ASCII characters. Conventionally, a list of Unicode code points is known as a
  charlist and a list of ASCII characters is a subset of it.
Raw representation
  [72, 101, 108, 108, 111, 44, 32, 87, 111, 114, 108, 100, 33]
Reference modules
  List
Implemented protocols
  Collectable, Enumerable, IEx.Info, Inspect, List.Chars, String.Chars
iex(9)>

Strings are encoded in UTF-8, so you can use special characters and even emojis.

iex(9)> IO.puts("Fabrizio De André")
Fabrizio De André
:ok

iex(10)> IO.puts("Hello, 🌎!")
Hello, 🌎!
:ok

It’s also possible to print a given character by specifying its UTF-8 codepoint.

iex(11)> > IO.puts("Hello, #{<<127758 :: utf8>>}!")
Hello, 🌎!
:ok

If you are familiar with Ruby, you’ll recognize the same string interpolation syntax in which the expression that needs to be evaluated is enclosed within #{}.

Windows users encountering issues related to special characters can improve their experience by changing the active console code page by executing chcp 65001 in their Command Prompt, before executing IEx.

It doesn’t get any simpler than a Hello World program, but as you can see, if you dig a little deeper, you can find out quite a few things about a given programming language.

In the next Elixir-related post, I’ll publish a similar discussion for another seemingly trivial problem: the length of a string in Elixir. It will give us an opportunity to discuss strings more deeply. Subscribe, if you don’t already, to be notified of its publication.

Footnotes

1. Atoms are constants whose values are their own names. The value of :ok is :ok. If you are familiar with Ruby, atoms are equivalent to symbols.
2. A glaring exception to the parentheses being optional are non-qualified/local calls with zero-arity. In those cases, parentheses are required to distinguish simple variables (e.g., user_list) from actual function calls (e.g., list_user()). To avoid ambiguity, it’s also important to include parentheses with one-arity functions within pipelines (e.g., "Hello, World!" |> IO.puts()). For stylistic recommendations of when to use parentheses and when to omit them, consider reading these two style guides (1, 2). At any rate, do not obsess over this. mix format or a properly configured editor will typically take care of applying idiomatic and consistent styling for you.

The post Elixir Hello World appeared first on Programming Zen.